Indgangspunkt for AntRunner-program

Ant-kerneplugin'en erklærer et overordnet indgangspunkt, der giver mulighed for at udføre Eclipses integrerede Ant-understøttelse i konsolløs tilstand. En Ant-bygning kan derefter udføres direkte fra platformens overordnede startprogram.

Her er et eksempel på en .bat-fil, der viser, hvordan du kan udnytte indgangspunktet for antRunner-programmet i Windows.

 
echo off
setlocal

REM ****************************************************

REM Den JRE-java.exe, der skal bruges
set JAVAEXE="C:\jdk1.4.2\jre\bin\java.exe"

REM Jar til start af Eclipse
set LAUNCHERJAR="C:\eclipse\plugins\org.eclipse.equinox.launcher_1.0.0.v20070319.jar"

REM Placeringen af arbejdsområdet
set WORKSPACE=C:\runtime-workspace

REM Den byggefil, der skal bruges til bygningen
set BUILDFILE=build.xml

REM ****************************************************

if not exist %JAVAEXE% echo ERROR: forkert java.exe=%JAVAEXE%, redigér denne fil, og ret JAVAEXE envar
if not exist %JAVAEXE% goto done

if not exist %LAUNCHERJAR% echo ERROR: forkert equinox.launcher jar=%LAUNCHERJAR%, redigér denne fil, og ret miljøvariablen LAUNCHERJAR
if not exist %LAUNCHERJAR% goto done

if not exist %WORKSPACE% echo ERROR: forkert workspace=%WORKSPACE%, redigér denne fil, og ret WORKSPACE envar
if not exist %WORKSPACE% goto done

if not exist %BUILDFILE% echo ERROR: forkert buildfile=%BUILDFILE%, redigér denne fil, og ret BUILDFILE envar
if not exist %BUILDFILE% goto done

:run
@echo on
%JAVAEXE% -cp %LAUNCHERJAR% org.eclipse.equinox.launcher.Main -noupdate -application org.eclipse.ant.core.antRunner -data %WORKSPACE% -buildfile %BUILDFILE%

:done
pause

Relaterede begreber
Ant-understøttelse