Eingangspunkt für AntRunner-Anwendung

Das Ant-Kern-Plug-in deklariert einen Haupteingangspunkt, der die Ausführung der in Eclipse integrierten Ant-Unterstützung in einer Umgebung ohne GUI ('Headless') ermöglicht. Ein Ant-Build kann dann direkt von dem Startprogramm der Hauptplattform ausgeführt werden.

Der folgende Absatz enthält ein Beispiel für eine .bat-Datei, die veranschaulicht, wie ein Eingangspunkt für eine AntRunner-Anwendung unter Windows genutzt wird.

 
echo off
setlocal

REM ****************************************************

REM Die zu verwendende JRE java.exe
set JAVAEXE="C:\jdk1.4.2\jre\bin\java.exe"

REM The Eclipse launcher jar
set LAUNCHERJAR="C:\eclipse\plugins\org.eclipse.equinox.launcher_1.0.0.v20070319.jar"

REM Die Position Ihres Arbeitsbereichs
set WORKSPACE=C:\runtime-workspace

REM Die zum Builden zu verwendende Builddatei
set BUILDFILE=build.xml

REM ****************************************************

if not exist %JAVAEXE% echo ERROR: incorrect java.exe=%JAVAEXE%, edit this file and correct the JAVAEXE envar
if not exist %JAVAEXE% goto done

if not exist %LAUNCHERJAR% echo ERROR: incorrect equinox.launcher jar=%LAUNCHERJAR%, edit this file and correct the LAUNCHERJAR envar
if not exist %LAUNCHERJAR% goto done

if not exist %WORKSPACE% echo ERROR: incorrect workspace=%WORKSPACE%, edit this file and correct the WORKSPACE envar
if not exist %WORKSPACE% goto done

if not exist %BUILDFILE% echo ERROR: incorrect buildfile=%BUILDFILE%, edit this file and correct the BUILDFILE envar
if not exist %BUILDFILE% goto done

:run
@echo on
%JAVAEXE% -cp %LAUNCHERJAR% org.eclipse.equinox.launcher.Main -noupdate -application org.eclipse.ant.core.antRunner -data %WORKSPACE% -buildfile %BUILDFILE%

:done
pause

Zugehörige Konzepte
Ant-Unterstützung