STKResonate
Prev | Orchestra Opcodes and Operators | Next

## STKResonate

STKResonate — STKResonate is a noise driven formant filter.

## Description

STKResonate is a noise driven formant filter. This instrument contains a noise source, which excites a biquad resonance filter, with volume controlled by an ADSR.

## Syntax

    asignal STKResonate ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 5 controller numbers and values that work for STKResonate are:

- kc, kv -- 2, frequency of resonance.

- kc, kv -- 4, pole radii.

- kc, kv -- 11, notch frequency.

- kc, kv -- 1, zero radii.

- kc, kv -- 128, gain of envelope.

| Note
The code for this opcode is taken directly from the Resonate class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKResonate opcode. It uses the file STKResonate.csd.

Example 803. Example of the STKResonate opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKResonate.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1 ; frequency of STKResonate has no effect on sound

    kpol	=	p4				;pole radii
    kfrq	line	100, p3, 0			;resonance freq + notch freq

    asig	STKResonate 1, 1, 2, kfrq, 4, kpol, 1, 10, 11, kfrq, 128, 127
    asig	=	asig * .7			;too loud
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1 0
    i 1 + . >
    i 1 + . >
    i 1 + . >
    i 1 + . 120
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKPlucked | Home | STKRhodey