monitor
Prev | Orchestra Opcodes and Operators | Next

## monitor

monitor — Returns the audio spout frame.

## Description

Returns the audio spout frame (if active), otherwise it returns zero.

## Syntax

    aout1 [,aout2 ... aoutX] monitor

## Performance

This opcode can be used for monitoring the output signal from csound. It should not be used for processing the signal further.

See the entry for the fout opcode for an example of usage of monitor.

## Examples

Here is an example of the monitor opcode. It uses the file monitor.csd.

Example 486. Example of the monitor opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o monitor.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    asig poscil3 .5, 880, giSine
    ;write a raw file: 32 bits with header
         fout "fout_880.wav", 15, asig
         outs asig, asig

    endin

    instr 2

    klfo lfo 1, 2, 0
    asig poscil3 .5*klfo, 220, giSine
    ;write an aiff file: 32 bits with header
         fout "fout_aif.aiff", 25, asig
    ;        fout "fout_all3.wav", 14, asig
         outs asig, asig

    endin

    instr 99 ;read the stereo csound output buffer

    allL, allR monitor
    ;write the output of csound to an audio file
    ;to a wav file: 16 bits with header
               fout "fout_all.wav", 14, allL, allR

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 0 3
    i 99 0 3
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

fout, the Mixer opcodes and the Zak Patching System.

## Credits

Istvan Varga 2006

Prev | Up | Next
modmatrix | Home | moog