Reference for Processing version 1.5. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, please let us know. If you prefer a more technical reference, visit the Processing Javadoc.

Name

### createReader()

Examples

    BufferedReader reader;
    String line;

    void setup() {
      // Open the file from the createWriter() example
      reader = createReader("positions.txt");
    }

    void draw() {
      try {
        line = reader.readLine();
      } catch (IOException e) {
        e.printStackTrace();
        line = null;
      }
      if (line == null) {
        // Stop reading because of an error or file is empty
        noLoop();
      } else {
        String[] pieces = split(line, TAB);
        int x = int(pieces[0]);
        int y = int(pieces[1]);
        point(x, y);
      }
    }

Description

Creates a BufferedReader object that can be used to read files line-by-line as individual String objects. This is the complement to the createWriter() function.
Starting with Processing release 0134, all files loaded and saved by the Processing API use UTF-8 encoding. In previous releases, the default encoding for your platform was used, which causes problems when files are moved to other platforms.

Syntax

    createReader(filename)

Parameters

filename | String: name of the file to be opened

Returns | BufferedReader or null
Usage | Web & Application
Related | BufferedReader createWriter() PrintWriter try catch

Updated on August 30, 2010 04:29:39pm EDT