##############################################
# Tutorial map 5: Gods and divine abilities  #
##############################################

{{
require("dlua/tutorial.lua")

tutorial5 = {}

function tutorial5.msg(text)
    return tutorial_msg("tutorial5 " .. text)
end

function tutorial5.exit()
    crawl.tutorial_msg("tutorial5 exit", true)
end

function tutorial5.win()
    crawl.mark_game_won()
    tutorial5.exit()
end
}}

NAME:    tutorial_lesson5
TAGS:    no_rotate no_monster_gen no_item_gen no_hmirror no_vmirror no_trap_gen no_pool_fixup tutorial
DESC:    "Lesson 5: Gods and Divine Abilities"
ORIENT:  encompass
KFEAT:   bABCDEHIJ = .
KFEAT:   F = +
COLOUR:  ABCDEHIJ = lightblue
FTILE:   ABCDEHIJ = tutorial_pad
KPROP:   b_ = bloody / nothing
KFEAT:   _ = altar_trog
NSUBST:  M = 2:= / *:m
ITEM:    mace ego:none not_cursed
ITEM:    book of clouds
MONS:    rat always_corpse
MONS:    hobgoblin ; short sword ego:none not_cursed | w:5 mace ego:none not_cursed
MONS:    gnoll ; flail ego:none not_cursed
MONS:    orc wizard spells:magic_dart;.;.;.;blink;blink
MARKER:  A = lua:tutorial5.msg("secret_door")
MARKER:  = = lua:tutorial5.msg("dungeon_overview")
MARKER:  _ = lua:tutorial5.msg("altar")
MARKER:  B = lua:tutorial5.msg("religion")
MARKER:  C = lua:tutorial5.msg("piety_on_kill")
MARKER:  D = lua:tutorial5.msg("sacrificing")
MARKER:  E = lua:tutorial5.msg("burn_book")
MARKER:  F = lua:tutorial5.msg("berserk")
MARKER:  H = lua:tutorial5.msg("exhaustion")
MARKER:  I = lua:tutorial5.msg("hunger")
MARKER:  J = lua:tutorial5.msg("berserk2")
MARKER:  { = lua:one_way_stair { dst  = "tutorial_lesson5", \
                                 onclimb = "tutorial5.exit" }
MARKER:  ( = lua:one_way_stair { dst  = "tutorial_lesson5", \
                                 onclimb = "tutorial5.exit" }
MARKER:  [ = lua:one_way_stair { dst  = "tutorial_lesson5", \
                                 onclimb = "tutorial5.exit" }
MARKER:  } = lua:tutorial5.msg("tutorial_end")
MARKER:  ) = lua:tutorial5.msg("tutorial_end")
MARKER:  ] = lua:tutorial5.msg("tutorial_end")
MARKER:  } = lua:one_way_stair { dst  = "tutorial_lesson5", \
                                 desc = "exit from the tutorial", \
                                 onclimb = "tutorial5.win" }
MARKER:  ) = lua:one_way_stair { dst  = "tutorial_lesson5", \
                                 desc = "exit from the tutorial", \
                                 onclimb = "tutorial5.win" }
MARKER:  ] = lua:one_way_stair { dst  = "tutorial_lesson5", \
                                 desc = "exit from the tutorial", \
                                 onclimb = "tutorial5.win" }
epilogue{{
  crawl.mesclr(true)
  crawl.tutorial_msg("tutorial5 start")
  tutorial_intro()
}}
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxx..1..xxxxxxxxxxxxxxxxxxxxxx.x}xxx
xxxxxxxxxxxxxxxx.....1.xxxxxxxxxxxxxxxxxxxx.....xx
xxxxxx....C......1.....xxxxxxxxxxxxxxxxxx....1...x
xxxxxx.xxxxxxxxx...1...xxxxxxxxxxxxxxxxx...2....)x
xxxxxx.xxxxxxxxxx.....xxxxxxxxxxxxxxJ....1....1xxx
xxxxxx.xxxxxxxxxxxxDxxxxxxxxxxxxxxx.xxxxx...2...xx
xxxxxxBxxxxxxxxxxxx.xxxxxxxxxxxxxxx.xxxxxxx..4.xxx
xtt..G.G..ttxxxxxxx.xxxxxxxxxxxxxxxx..xxxxxx.]xxxx
xt........txxxxxxxx.xxxxxxxxxxxxxxxxxx.xxxxxxxxxxx
x..mmmMmmm..xxxxxxx.xxxxxxxxxxxxxxxxxxx...xxxxxxxx
x..mYbbbYm..xxxxxxxExxxxxxxxxxxxxxxxxx..1...xxxxxx
x..Mbb_bbM..xxxxxxx.xxxxxxxxxxxxxxxxxxx..1...xxxxx
x..mVbbbVm..xxxxxxx.xxxxxxxxxxxxxxxxxxxx....xxxxxx
x..mmmmmmm..xxxxxxx.xxxxxxxxxxxxxxxxxxxxxxxx.xxxxx
xt.........txxxxxxxexxxxxxxxxxxxxxxxxxxxxxxxxIxxxx
xtt..G.G..ttxxxxx.....xxxxxxxx.......xxxxxx..xxxxx
xxxxxxAxxxxxxxxxx............F.....3.H.....xxxxxxx
xxxxxx.xxxxxxxxxx.....xxxxxxxx.......xxxxxxxxxxxxx
xxxxxx.xxxxxxxxxx.2...xxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxx+xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxx...d...xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxx.[.{.(.xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP
